UTILIZANDO PROC FORMAT DE SAS

En una entrada anterior nos referíamos a las posibilidades que brindan paquetes estadísticos como SAS o R para obtener tablas bien presentadas sin necesidad de incluir en los conjuntos de datos variables de cadena. Para el caso de SAS, hacíamos referencia al procedimiento “proc format”, que construye formatos de etiquetas de valor que pueden ser utilizados por procedimientos de tabulación como proc tabulate, proc report o proc print, entre otros.

Hoy vamos a ver un ejemplo práctico, que cruza las razones para escoger a una empresa o a una persona con el estadio de sistematización en que se encuentra la entidad.

proc format;

value estadio 1='1. Primer estadio de sistematizacion interna'

2='2. Segundo estadio de sistematización interna'

3='3. Tercer estadio de sistematización interna'

4='4. Cuarto estadio de sistematización interna';

run;

proc tabulate data=sasuser.basefinal ;

title1 'Principales razones para escoger a la empresa o persona'; 

title2 'Función 1: Ventas – telemarketing y ventas móviles';

title3 'Según Estadios de sistematización interna';

title4 'Al 80% del directorio';

class estadio;

var F89 F90 F91 F92 F93 F94 F95 F97;

keylabel n='' mean=' ' all='Total';

table all estadio, n*f89='     '

mean*f89='Precio'*f=nlpcti8.2

mean*f90='Cercanía geográfica'*f=nlpcti8.2

mean*f91='Reconocimiento en el mercado'*f=nlpcti8.2

mean*f92='Por sus conocimientos, experiencia'*f=nlpcti8.2

mean*f93='Por su infraestructura y equipos'*f=nlpcti8.2

mean*f94='Porque existían vinculos anteriores y relaciones de confianza'*f=nlpcti8.2

mean*f95='Porque pertenece al mismo grupo empresarial'*f=nlpcti8.2

mean*f97='Otra'*f=nlpcti8.2;

format estadio estadio.;

footnote 'Fuente: DANE y Universidad Nacional';

run;

Como se observa, el código incluye un "proc format" llamado "estadio", que se llama en el "proc tabulate" para la variable estadio (numérica).

El resultado de la ejecución de este código es un cuadro de salida que incluye las etiquetas de los valores, utilizando únicamente una variable numérica. Lo que aporta eficiencia al trabajo.